Aller au contenu
PlaidCloud

Créer un rapport avec les fonctions personnalisées

Un rapport PlaidXL est une grille Excel ordinaire : les nœuds d’une dimension sur le côté, ceux d’une autre dimension en haut, et à chaque intersection une formule PLAIDXL.CELL qui consolide une mesure à partir d’une table PlaidCloud. Les chiffres étant des formules, le rapport se recalcule à partir des données actuelles au lieu d’être reconstruit chaque mois.

lignes issues de PLAIDXL.DRILLRegionFY2025FY2026TotalEMEAAPACAmericas=CELL(…)PLAIDXL.CELL combineTABLE_REPR(“Sales”)MEASURE(“revenue”)MEASURE_TYPE(“sum”)DIMENSION_REPR(“Region”, row)DIMENSION_REPR(“Period”, column)→ chiffre d’affaires de EMEA en FY2026
Chaque cellule prend le nœud de sa ligne et celui de sa colonne, puis consolide la mesure selon les deux.

Avant de commencer

Section intitulée « Avant de commencer »
  • Connectez-vous et sélectionnez le projet qui contient vos données.
  • Il vous faut une table avec une colonne numérique à analyser, par exemple revenue, et une colonne pour chaque dimension selon laquelle vous souhaitez produire le rapport, par exemple Region et Period, liée à cette dimension dans PlaidCloud. CELL filtre par nom de colonne et ne consolide un nœud à travers sa dimension que sur une colonne liée. Consultez Valeurs.
  • Vous n’êtes pas sûr des noms exacts ? =PLAIDXL.TABLE.TBL_LIST(), =PLAIDXL.TABLE.GET_COLUMNS("Sales") et =PLAIDXL.DIMENSION.DIM_LIST() les listent dans une feuille de travail.

Créer le rapport

Section intitulée « Créer le rapport »

Les étapes utilisent une table nommée Sales, avec la colonne de mesure revenue et les colonnes de dimension Region (lignes) et Period (colonnes), liées à des dimensions du même nom. Remplacez-les par vos propres noms : dans DRILL, utilisez le nom de la dimension, et dans DIMENSION_REPR, le nom de la colonne de la table.

  1. Décrivez ce que vous mesurez. Dans trois cellules en haut de la feuille, saisissez :

    B1  =PLAIDXL.REPR.TABLE_REPR("Sales")
    B2  =PLAIDXL.REPR.MEASURE("revenue")
    B3  =PLAIDXL.REPR.MEASURE_TYPE("sum")

    Chaque valeur du rapport fait référence à ces cellules : en modifier une, par exemple "mean" au lieu de "sum", change l’ensemble du rapport.

  2. Disposez les lignes. Dans A6, déroulez la dimension des lignes à partir de son nœud supérieur :

    A6  =PLAIDXL.DRILL("Region", "Total", PLAIDXL.REPR.DRILL_KEY("1 level"))

    Total et ses enfants se déversent dans la colonne A, en retrait sous leur parent et regroupés pour que vous puissiez les réduire. Utilisez "all" pour tous les niveaux, ou "leaves" pour le seul niveau inférieur. Pour saisir vous-même les nœuds des lignes, placez un nom de nœud dans chaque cellule.

  3. Disposez les colonnes. Saisissez les nœuds des colonnes sur la ligne 5, à partir de B5, par exemple FY2025 et FY2026.

  4. Renseignez la première valeur. Dans B6, saisissez :

    =PLAIDXL.CELL($B$1, $B$2, $B$3, PLAIDXL.REPR.DIMENSION_REPR("Region", $A6), PLAIDXL.REPR.DIMENSION_REPR("Period", B$5))

    Les signes $ figent la table, la mesure et le type, le nœud de ligne dans la colonne A et le nœud de colonne sur la ligne 5. Le retrait que DRILL ajoute aux noms de nœuds est ignoré.

  5. Remplissez la grille. Copiez B6 vers la droite jusqu’à votre dernière période et vers le bas jusqu’à votre dernière ligne. Chaque cellule affiche le chiffre d’affaires de la région de sa ligne pour la période de sa colonne.

Pour ajouter un filtre qui s’applique à l’ensemble du rapport, par exemple une seule gamme de produits, ajoutez un autre DIMENSION_REPR dans une cellule en haut, tel que B4 =PLAIDXL.REPR.DIMENSION_REPR("Product", "Hardware"), puis transmettez $B$4 à chaque CELL.

Pour afficher plusieurs mesures pour chaque ligne, utilisez PLAIDXL.CELLS avec PLAIDXL.REPR.MEASURES.

Garder le rapport à jour

Section intitulée « Garder le rapport à jour »
  • Forcez un recalcul complet pour récupérer les valeurs actuelles dans chaque formule PlaidXL : sous Windows, appuyez sur Ctrl+Alt+F9. Un recalcul ordinaire ne récupère pas de nouveau les données, sauf si les arguments d’une formule ont changé.
  • Modifiez le périmètre en changeant une cellule de base : une autre table, une autre mesure ou agrégation, ou un autre nœud de filtre de niveau supérieur. Les formules qui utilisent cette cellule sont mises à jour immédiatement.
  • Produisez le rapport pour un autre projet en le sélectionnant dans le volet des tâches, puis en forçant un recalcul complet. Les formules lisent le projet actuellement sélectionné : un même classeur peut donc servir pour chaque projet qui partage les mêmes noms de table, de colonne et de dimension.

Partager une copie contenant uniquement les valeurs

Section intitulée « Partager une copie contenant uniquement les valeurs »

Les personnes qui n’ont pas PlaidXL, ou qui n’ont pas accès au projet, voient des erreurs à la place des formules PlaidXL. Pour leur envoyer les chiffres, remplacez d’abord les formules par leurs valeurs :

  1. Enregistrez votre rapport, puis enregistrez une copie sous un nouveau nom pour l’envoi.
  2. Dans la copie, cliquez sur PlaidCloud → Sanitize Workbook.
  3. Envoyez la copie.

Sanitize Workbook remplace chaque formule du classeur par sa valeur actuelle. Restore Workbook rétablit les formules, mais il ne restaure pas correctement les formules dont les résultats se déversent, comme DRILL, et il écrase tout ce que vous avez modifié après le nettoyage. Conservez votre original : c’est le moyen fiable de retrouver votre rapport dynamique. Consultez Nettoyer et restaurer.

Voir aussi

Section intitulée « Voir aussi »