Criar um relatório com funções personalizadas

Um relatório PlaidXL é uma grelha Excel normal: os nós de uma dimensão ao longo do lado, os nós de outra dimensão ao longo do topo e, em cada interseção, uma fórmula PLAIDXL.CELL que agrega uma medida a partir de uma tabela do PlaidCloud. Como os números são fórmulas, o relatório volta a calcular-se com os dados atuais em vez de ter de ser refeito todos os meses.

Cada célula recebe o nó da sua linha e o nó da sua coluna, e agrega a medida segundo ambos.

Antes de começar

• Inicie sessão e selecione o projeto que contém os seus dados.
• Precisa de uma tabela com uma coluna numérica sobre a qual elaborar o relatório, como revenue, e de uma coluna para cada dimensão pela qual vai elaborar o relatório, como Region e Period, associada a essa dimensão no PlaidCloud. A função CELL filtra pelo nome da coluna e só agrega um nó através da respetiva dimensão numa coluna associada. Consulte Valores.
• Não tem a certeza dos nomes exatos? =PLAIDXL.TABLE.TBL_LIST(), =PLAIDXL.TABLE.GET_COLUMNS("Sales") e =PLAIDXL.DIMENSION.DIM_LIST() apresentam-nos numa folha de rascunho.

Criar o relatório

Os passos usam uma tabela com o nome Sales, com a coluna de medida revenue e as colunas de dimensão Region (linhas) e Period (colunas), associadas a dimensões com os mesmos nomes. Substitua-os pelos seus próprios nomes — em DRILL use o nome da dimensão e em DIMENSION_REPR o nome da coluna da tabela.

1. Descreva o que está a medir. Em três células no topo da folha, introduza:

   B1  =PLAIDXL.REPR.TABLE_REPR("Sales")
   B2  =PLAIDXL.REPR.MEASURE("revenue")
   B3  =PLAIDXL.REPR.MEASURE_TYPE("sum")

   Todos os valores do relatório remetem para estas células, pelo que alterar uma delas — "mean" em vez de "sum", por exemplo — altera o relatório inteiro.

2. Disponha as linhas. Em A6, percorra a dimensão das linhas a partir do respetivo nó de topo:

   A6  =PLAIDXL.DRILL("Region", "Total", PLAIDXL.REPR.DRILL_KEY("1 level"))

   Total e os respetivos filhos expandem-se pela coluna A, indentados sob o nó superior e agrupados para que possa recolhê-los. Use "all" para todos os níveis ou "leaves" apenas para o nível mais baixo. Para escrever os nós das linhas manualmente, coloque um nome de nó em cada célula.

3. Disponha as colunas. Escreva os nós das colunas ao longo da linha 5, começando em B5 — por exemplo, FY2025 e FY2026.

4. Preencha o primeiro valor. Em B6, introduza:

   =PLAIDXL.CELL($B$1, $B$2, $B$3, PLAIDXL.REPR.DIMENSION_REPR("Region", $A6), PLAIDXL.REPR.DIMENSION_REPR("Period", B$5))

   Os sinais $ mantêm fixos a tabela, a medida e o tipo, o nó da linha na coluna A e o nó da coluna na linha 5. A indentação que DRILL acrescenta aos nomes dos nós é ignorada.

5. Preencha a grelha. Copie B6 para a direita até ao último período e para baixo até à última linha. Cada célula mostra a receita da região da respetiva linha no período da respetiva coluna.

Para adicionar um filtro que se aplique a todo o relatório — uma linha de produtos, por exemplo — adicione outro DIMENSION_REPR numa célula no topo, como B4 =PLAIDXL.REPR.DIMENSION_REPR("Product", "Hardware"), e passe $B$4 a cada CELL.

Para mostrar várias medidas em cada linha, use PLAIDXL.CELLS com PLAIDXL.REPR.MEASURES.

Manter o relatório atualizado

• Force um novo cálculo completo para obter os valores atuais em todas as fórmulas PlaidXL — no Windows, prima Ctrl+Alt+F9. Um novo cálculo normal não volta a obter os dados, a menos que os argumentos de uma fórmula tenham mudado.
• Altere o âmbito editando uma célula de blocos de construção: outra tabela, medida ou agregação, ou outro nó de filtro de nível superior. As fórmulas que usam a célula são atualizadas de imediato.
• Elabore o relatório de outro projeto selecionando-o no painel de tarefas e, em seguida, forçando um novo cálculo completo. As fórmulas leem do projeto que estiver selecionado, pelo que o mesmo livro pode servir para cada projeto que partilhe os mesmos nomes de tabela, coluna e dimensão.

Partilhar uma cópia apenas com valores

Quem não tem o PlaidXL, ou não tem acesso ao projeto, vê erros no lugar das fórmulas PlaidXL. Para lhes enviar os números, substitua primeiro as fórmulas pelos respetivos valores:

1. Guarde o seu relatório e, em seguida, guarde uma cópia com um novo nome para enviar.
2. Na cópia, clique em PlaidCloud → Sanitize Workbook.
3. Envie a cópia.

Sanitize Workbook substitui todas as fórmulas do livro pelo respetivo valor atual. Restore Workbook repõe as fórmulas, mas não repõe corretamente as fórmulas cujos resultados se expandem, como DRILL, e substitui tudo o que tenha alterado depois da sanitização. Guarde o original — é a forma fiável de recuperar o seu relatório em direto. Consulte Sanitizar e restaurar.

Cuidado

Sanitize a cópia que vai enviar, nunca o seu único relatório de trabalho. A sanitização afeta todas as fórmulas do livro, incluindo as que não são funções PlaidXL.

Ver também

• Funções personalizadas do PlaidXL — todas as funções e argumentos
• O friso do PlaidCloud — percorrer a partir de duas células e sanitizar para partilhar
• Conceber uma hierarquia da dimensão — crie a hierarquia na qual as suas linhas são agregadas